;***********************************************************************************************************************
;															
;	PIN-PLA-3DC-1	PINTA Y PLANIFICA SUPERFICIEL DE (3DCARAS-PANAS) Pide Color RALLA y NUMERA 3DCARA		
;															
;***********************************************************************************************************************



;															
;	FIJA PUNTOS BASE Y PUNTOS DE 3DCARA										
;															
;	ENTRADAS: NINGUNA												
;	SALIDAS : P1 P2 P3 P4 PP0 PPX											
;	LONALES : W1 													
;															

(DEFUN FIJA-P ( / W1)

	(COMMAND "-REFENT" "FIN")
	(SETQ PP0 (GETPOINT     " Seleciona  PUNTO ORIGEN BASE ( 1º IZQUIERDA RALLA (2D)) (PP0): ? ")) (TERPRI)
	(SETQ PPX (GETPOINT PP0 " Seleciona  PUNTO EJE-X BASE  ( 2º DERECHA (2D)) (PPX): ? ")) (TERPRI)
	(SETQ P1  (GETPOINT     " Seleciona  PRIMER PUNTO ( 1º IZQUIERDA RALLA (3D)) (P1): ? ")) (TERPRI)
	(SETQ P2  (GETPOINT P1  " Seleciona SEGUNDO PUNTO ( 2º DERECHA (3D)) (P2): ? ")) (TERPRI)
	(COMMAND "-REFENT" "DES")

	(SETQ W1 T)
	(WHILE W1
		(COMMAND "-REFENT" "FIN")
		(SETQ P3 (GETPOINT P2 " Seleciona SIGUIENTE PRIMER PUNTO ( 1º IZQUIERDA RALLA (3D)) (P3) (SALIR => ENTER): ? ")) (TERPRI)
		(COMMAND "-REFENT" "DES")

		(IF (= P3 nil) (SETQ W1 nil)
		(PROGN
			(COMMAND "-REFENT" "FIN")
			(SETQ P4 (GETPOINT P3 " Seleciona SIGUIENTE SEGUNDO PUNTO ( 2º DERECHA (3D)) (P4): ? ")) (TERPRI)
			(COMMAND "-REFENT" "DES")

			(PLANI)

			(SETQ P1 P3 P2 P4)
		) ; PROGN
		) ; IF

	) ; WHILE
) ; defun FIJA-P

;															



;															
;	PINTA (3DCARA-Plana) EN EL ESPACIO Y EN EL PLANO								
;															
;	ENTRADAS: P1 P2 P3 P4 PP0 PPX											
;	SALIDAS : NINGUNA												
;	LOCALES : P1A P2A P3A P4A P1AU P2AU P3AU P4AU									
;															

(DEFUN PLANI ( / P1A P2A P3A P4A P1AU P2AU P3AU P4AU)


	(SETQ NX (+ NX 1))

	(COMMAND "COLOR" 5) (COMMAND "3DCARA" P1 P2 P4 P3 "") ; PLANO 3D
	(COMMAND "COLOR" COR) (COMMAND "LINEA" P1 P3 "")


	(COMMAND "SCP" "3P" P1 P2 P3)	; PLANO-3D-TXT
	(COMMAND "COLOR" COR) (COMMAND "TEXTO" (LIST 1 0.3 0) '0.5 "" NX)
	(COMMAND "SCP" "U")


	(COMMAND "SCP" "3P" P1 P2 P3)	; PLANO-3D-A
	(SETQ P1A (TRANS P1 0 1))
	(SETQ P2A (TRANS P2 0 1))
	(SETQ P3A (TRANS P3 0 1))
	(SETQ P4A (TRANS P4 0 1))
	(COMMAND "SCP" "U")

	(SETQ P1A (LIST (CAR P1A) (CADR P1A) 0))
	(SETQ P2A (LIST (CAR P2A) (CADR P2A) 0))
	(SETQ P3A (LIST (CAR P3A) (CADR P3A) 0))
	(SETQ P4A (LIST (CAR P4A) (CADR P4A) 0))

	; PP0 y PPX PUNTOS BASE DE 3DCARA EN EL PLANO									
	(COMMAND "SCP" "3P" PP0 PPX "")	; PLANO-2D-X
	(SETQ P1AU (TRANS P1A 1 0))
	(SETQ P2AU (TRANS P2A 1 0))
	(SETQ P3AU (TRANS P3A 1 0))
	(SETQ P4AU (TRANS P4A 1 0))
	(COMMAND "SCP" "U")

	(COMMAND "COLOR" 5) (COMMAND "3DCARA" P1AU P2AU P4AU P3AU "") ; PLANO 2D
	(COMMAND "COLOR" COR) (COMMAND "LINEA" P1AU P3AU "")


	(COMMAND "SCP" "3P" P1AU P2AU P3AU)	; PLANO-2D-TXT
	(COMMAND "COLOR" COR) (COMMAND "TEXTO" (LIST 1 0.3 0) '0.5 "" NX)
	(COMMAND "SCP" "U")


	(SETQ PP0 P3AU PPX P4AU)

) ; defun PLANI

;															



;															
;       *** PROGRAMA *** PROGRAMA *** PROGRAMA *** PROGRAMA *** PROGRAMA*** PROGRAMA*** 				
;															
;	ENTRADAS: NINGUNA												
;	SALIDAS : NINGUNA												
;	LONALES : P1 P2 P3 P4 PP0 PPX											
;															

(DEFUN C:PIN-PLA-3DC-1 (/ P1 P2 P3 P4 PP0 PPX)
	(SETVAR "blipmode" 0) (SETVAR "cmdecho" 0) (GRAPHSCR)
	(COMMAND "-REFENT" "DES") (COMMAND "SCP" "U")

	(SETQ COR (GETINT "     Nº COLOR RALLA (1=ROJO 2=AMARILLO 3=VERDE): ?  "))

	(SETQ N0  (GETINT "     Nº 3DCARA (Antirior a PINTAR) <0>: ?  ")) (TERPRI)

	(SETQ NX N0)

	(FIJA-P)

	(SETVAR "blipmode" 1) (SETVAR "cmdecho" 1) (PRIN1 "            PROGRAMA CERRADO         ")
) ;cierre DEFUN PIN-PLA-3DC-1

;															
